# Maintainer: Kira <[@kira](https://dev.kira-linux.org/kira)>

pkgname=bzz-initrd
pkgver=0.0.1
pkgrel=1
pkgdesc='Initrd image for Kira Linux'
url='https://dev.kira-linux.org'
arch=(x86_64)

_nyanit_ver=0.1.0-rc2
_nyanit_src=v${_nyanit_ver}.tar.gz

makedepends=(
  bcachefs-tools
  coreutils
  pax-utils
  bc
  cpio
  gettext
  pahole
  perl
  python
  rust
  tar
  xz
  gzip
  zstd
)
options=(
  !debug
)

_nyanit_src_dir=nyanit

source=(
  https://dev.kira-linux.org/kira-linux/nyanit/archive/${_nyanit_src}
)

sha256sums=('a72256b6fc705cb1a20486edcddc4b1d46d41c83cb0438a4697242d31d3be2b9')
b2sums=('d44d8211d5c28f55e271e1b93f3967696c0ee701f1c9649ba01ce23463303c528d7a54a51decf202f57dcf205ece785df642056b634a756fcb177619e1979119')

_tools_list=(
  /usr/bin/mount
  /usr/bin/umount
  /usr/bin/bcachefs
  /usr/bin/fsck
  /usr/bin/fsck.vfat
  /usr/bin/switch_root
  /usr/bin/ls
)

build() {

  echo "Populate initdramfs tree..."
  mkdir -p initramfs/{bin,lib,lib64,dev,proc,sys,new_root}

  echo "Building NYANIT..."
  cd $_nyanit_src_dir
  cargo build --release
  cp target/release/nyanit $srcdir/initramfs/nyanit
  chmod +x $srcdir/initramfs/nyanit
  echo "##### DONE Building NYANIT #####"
  echo ""

  echo "Copy libs and binaries"
  cd $srcdir
  lddtree --copy-to-tree $srcdir/initramfs "${_tools_list[@]}"

  # Create cpio archive
  echo "Create compressed cpio archive"
  cd $srcdir/initramfs
  find . -print0 | cpio --null -ov --format=newc > ../initramfs.cpio

}

package() {
  pkgdesc="The $pkgdesc kernel and modules"
  license=(
    GPL-3.0-or-later
    GPL-2.0-or-later
    GPL-2.0-only
    Zlib
  )

  echo "Installing bzz-initrd"
  install -vDm 644 $srcdir/initramfs.cpio -t "$pkgdir/usr/share/$pkgname/"
}

